Build a live ESP32 dashboard with gauges, charts and controls

#include <Arduino.h>
#include <WiFi.h>

// Your firmware version. Change it for every build you upload: the
// console counts an update done once the board reports it.
#define CLAVDA_FIRMWARE_VERSION "1.0.0"

// The library, then this board's credentials from the console.
#include <ClavdaOTA.h>
#include "clavda_device.h"

const char *ssid = "your-wifi";
const char *password = "your-wifi-password";

const int LED_PIN = 2;

// One ClavdaWidget per widget on the dashboard. The text in quotes is the
// widget's ID: copy it from the widget's settings in the console.
ClavdaWidget temperature("temperature");  // Value or Gauge card
ClavdaWidget history("temp_history");     // Line chart
ClavdaWidget status("status");            // Status card
ClavdaWidget led("led");                  // Toggle
ClavdaWidget brightness("brightness");    // Slider, 0 to 255

bool ledOn = false;
int ledLevel = 128;
unsigned long lastSample = 0;

void showLed() {
  analogWrite(LED_PIN, ledOn ? ledLevel : 0);
}

void setup() {
  Serial.begin(115200);

  // Controls: these run when someone uses the toggle or slider.
  led.onChange([](const ClavdaInput &in) {
    ledOn = in.asBool();
    showLed();
    if (ledOn) status.set("LED on", CLAVDA_SUCCESS);
    else status.set("LED off", CLAVDA_INFO);
  });
  brightness.onChange([](const ClavdaInput &in) {
    ledLevel = in.asInt();
    showLed();
  });

  // Starting values, so a dashboard opened now has something to show.
  led.set(ledOn);
  brightness.set(ledLevel);
  status.set("Starting", CLAVDA_INFO);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  ClavdaOTA.begin(CLAVDA_DEVICE);
}

void loop() {
  ClavdaOTA.loop();

  // Display: a reading every 2 s. set() only sends when it changes.
  if (millis() - lastSample >= 2000) {
    lastSample = millis();
    float celsius = temperatureRead();  // the chip's own sensor
    temperature.set(celsius);
    history.add(celsius);               // the console adds the time
  }
}